ボタン・ラベルウィジェット

■ ボタンウィジェット

ボタンを押すことで，アクションがコールバックされるGUIの基本的ウィジェットです．

　書式：　$child = $parent->Button(?options?)

　主なオプション：

• $button->flash ・・・ボタンを点滅させる
• $button->invoke　・・・　-command以下を実行する

　補足：

• -textvariable は状況に応じてボタンの表示を変えたいときに便利（例：処理の中断→完了）．リファレンスで指定すること．
• -commandで無名配列を使う場合と，無名サブルーチンを使う場合では以下の違いがある．
  • -command => [ \&Print_msg, $msg] ・・・$msgはボタンを作った時の値に固定される．
  • -command => sub { Print_msg($msg) } ・・・$msgはボタンを押したときの値が展開される．
• -reliefのデフォルトはraised
• 色の指定は，RGB指定（'#rrggbb'）か，X11のカラー名を使う(showrgb | less)．
• 他のオプションは，perldoc Tk::Button　または， perldoc Tk::optionsを参照のこと．

■ラベルウィジェット

文字列や画像などGUI上のラベルをつけるためのウィジェットです．何のイベント・アクションも起こしませんが，見栄えが命であるGUIにおいて，必須のものです．オプションはボタンのものと大体同様です．

　書式：　$child = $parent->Label(?options?)

　主なオプション：

　補足：

• 他のオプションは，perldoc Tk::Label または， perldoc Tk::optionsを参照のこと．

■　ボタンとラベルを使ったGUIプログラミング

2種類のウィジェットとpackを使って，簡単なGUIを作成してみましょう．以下にサンプルを示します．なお，プログラムと同じディレクトリに " Xcamel.gif "という画像ファイルを置いています．

#!/usr/bin/perl -w

use Tk;

%doremi = (
            "ド",     "ドはドーナツのド",
            "レ",     "レはレモンのレ",
            "ミ",     "ミはみんなのミ",
            "ファ",   "ファはファイトのファ",
            "ソ",     "ソは青い空",
            "ラ",     "ラはラッパのラ",
            "シ",     "シは幸せよ"
            );
@bgcolor = qw/red orange yellow green cyan blue purple/;

$msg = "歌いましょう!! 右のボタンを押してください";

$mw = MainWindow->new;
$mw->title('Do-re-mi');

$mw->Label(-text=>"Perl/Tkラクダのドレミ",
           -relief=> 'ridge',
           -padx => 5,
           -pady => 5,
           -anchor=> 'nw',
           -foreground => 'red')
    ->pack(-fill=>'both',
           -expand=>'yes',
           -side=>'top');

$mw->Button(-text => "終了",
           -command => sub { exit; }
           )
    ->pack(-fill=>'both',
           -expand=> 'yes',
           -side=>'bottom');

$mw->Label(-image=> $mw->Photo(-file=>'Xcamel.gif'),
           -borderwidth=>3,
           -relief=> 'sunken')
   -> pack(-side=>'left',
           -padx=> 5,
           -pady=> 5);

$mw->Label(-textvariable => \$msg,
           -anchor=> 'w',
           -background=> 'white',
           -relief=>'sunken',
           -width => 40
           )
   -> pack(-side=>'left',
           -padx=>5);

foreach $i (qw/ド レ ミ ファ ソ ラ シ/){
   $mw->Button(-text=> $i,
               -width=> 3,
               -background => shift(@bgcolor),
               -command => [ \&Sing_msg, $i ]
            )
   ->pack(-side=>'left');
}

MainLoop;

sub Sing_msg {
    my $key = $_[0];
    $msg = "♪ ".$doremi{$key}." ♪";
}

#----
#doremi.pl